Curvas de disonancias 

Investigación composicional sobre curvas de disonancia

Juan S. Lach Lau

Aspereza:

Las sensaciones de batimiento y aspereza son fluctuaciones de amplitud que ocurren debido a la interferencia constructiva y destructiva de las ondas sonoras.
El término 'aspereza' es análogo a sensaciones táctiles en el sentido de pequeñas irregularidades en la percepción del sonido.

La rapidez de las fluctuaciones de amplitud que forman dos ondas que se sobreponen es igual a su diferencia en Hz. Ondas cuya diferencia es menor a 20Hz producen fluctuaciones lentas que se perciben como trémolo o batimientos. Fluctuaciones más rápidas son las responsables de las sensaciones de aspereza. Las diferencias de frecuencia (o intervalos musicales) que producen mayor sensación de aspereza varían con el registro de la escucha. Esta variación está en función de la fisiología de la cóclea y se llama la banda crítica.

f = [37,52,74,105,149,210,297,420,595,841,1189,1682,2378,3364,4757,6727,9514,13454];
a = f.asBark.criticalBW;
// x = log de la frecuencia, y = tamaño de la banda crítica;
f.collect{|x,i| x + a[i]}.plot; // en hertz
f.collect{|x,i| x.cents(x+a[i]).abs}.plot; // en cents

b = Array.series(60, 0, 0.2).barkToHz; // una escala con grados de 0.2 barks
Pbind(\freq, Pseq(b,1), \dur, 0.25).play;

Ha habido un fuerte debate musicológico acerca cómo ocurren los fenómenos de consonancia y disonancia. Se tiene que la percepción de la disonancia es influenciada por factores culturales y sensoriales. Los factores adquiridos son muchos y dependen de la tradición y práctica de las distintas músicas. Los factores innatos (los mecanismos fisiológicos) han sido el foco de la disonancia psicoacústica, llevando hacia un concepto de disonancia basado en aspectos sensoriales del sonido, por lo cual se le refiere también como disonancia sensorial, un término acuñado por Helmholtz (1877) quien primero investigó los principios detrás de la percepción de disonancia como fluctuaciones de amplitud generados por los componentes espectrales del sonido. Depende de la alineación de los parciales entre sí asi como del intervalo que hay entre ellos y el registro en el que se encuentran.    

Vassilakis (2001 [1]), escribe: "Las configuraciones sonoras que tienen que ver con esta sensación se encuentran en la mayoría de las tradiciones musicales. En la tradición occidental, la sensación de aspereza ha sido vinculada a los conceptos de consonancia y disonancia, tanto si se les entiende como cargados estéticamente o no. Los estudios que abordan esta sensación han sido ocasionalmente muy enfáticos en encontrar una justificación universalmente aceptable de la 'inevitabilidad natural' y la 'superioridad estética' de la teoría musical occidental. Esto ha impedido que se examine seriamente las correlaciones físicas y fisiológicas de la sensación de aspereza. Al contrario, Helmoltz, el primer investigador que examinó la aspereza teórica y experimentalmente como un atributo importante de la sensación auditiva concluyó:
            
                'El que una combinación [de tonos] sea más áspera o suave que otra depende
                solamente de la estructura anatómica del oído y no tiene nada que ver con motivos
                psicológicos. Cualquiera que sea el grado de aspereza al que un escucha esté
                inclinado...como medio de expresión musical, depende del gusto y el hábito; por
                lo tanto la frontera entre consonancias y disonancias ha cambiado frecuentemente
                ... y seguirá cambiando.' "
                

En resumen, después de Helmholtz tenemos:

        von Békésy (1930's):             membrana basilar y fisiología de la cóclea
        Fletcher-Mundson(1930's):     curvas de igual intensidad
         
        Zwicker (1957):                    mediciones de la banda crítica
        Plomp-Levelt (1965):            relaciones entre la medida de la banda crítica y  consonancia
        Terhardt, Parncutt, etc.:         altura virtual, 'saliencia', etc.            

// una curva de disonancia para 1 sólo parcial nos da la curva de Plomp & Levelt
// (aspereza en función de la frecuencia)
Dissonance.make([100],[1],1.0, 2.5).plot;

// Aspereza de ondas senoidales en barks:
(
    SynthDef(\sine, {|freq = 440, amp = 0.005, pan = 0|
            var env = EnvGen.kr(Env.asr(0.1, amp, 0.2), doneAction:2);
            Out.ar(0, Pan2.ar(SinOsc.ar(freq), pan, env))
    }).memStore;
    
    z = ();
    z.win = SCWindow("rough", Rect(65, 90, 150,210));
    z.view = SCCompositeView(z.win, Rect(5,5,140,185));
    z.view.background = Color.gray(0.6);
    z.view.decorator = FlowLayout(z.view.bounds);
    z.knob = EZKnob(z.view, 120@40, "barks", [0.0,1.0, \linear, 0.001, 0.0, ].asSpec, numberWidth: 50); // the example uses EZKnob, available as a Quark..
    z.knob.action = {|k|
        z.b.do{|x,i| x[1].set(\freq, (z.a[i].asBark + k.value).barkToHz) };
    };
    z.knob.knobView.keystep = 0.003;
    z.win.onClose = { s.freeAll};
    z.win.front;
)    
z.a = Array.geom(4, 100, 2); // senoidales en octavas
// distintas combinaciones senoidales:
z.a = Array.series(10, 147, 147); // una serie de armónicos
z.a = [392, 392 * 5/4, 392 * 3/2]; // un acorde mayor justo
z.a = [392, 392 * 6/5, 392 * 3/2]; // un acorde menor justo
z.a = Array.series(20, 0, 1).barkToHz; // una escala de 1 bark (no interacción entre parciales a 0 barks)
z.a = Array.series(20, 0, 0.3).barkToHz; // una escala de 0.3 barks (muy áspera!)

z.b = z.a.collect{|x| {Synth(\sine, [\freq, x, \amp, z.a.size.reciprocal/2])}!2};
//Como se puede escuchar al mover la perilla, la aspereza es máxima alrededor de
// 0.25 barks, después de 0.3-0.4, los sonidos individuales se escuchan separados

Consonancia y disonancia:

.Tenney (1988, [2]) ha ayudado a clarificar que los términos 'consonancia' y 'disonancia' se refieren a distintos fenómenos dependiendo de su uso en distintos contextos históricos. En este sentido, la disonancia sensorial es lo que él llama 'Concepto de Consonancia-Disonancia 5', un concepto tímbrico que tiene pocas correlaciones con la teoría de armonía, aunque guarda afinidades con las técnicas de orquestación. Es también importante distinguir entre concepciones, teorías explicativas, usos prácticos y actitudes estéticas hacia los conceptos de consonancia-disonancia. Sus otros conceptos de consonancia-disonancia son:

            CCD                             Textura                                    Afinación
            1: melódica                 heterofonía, monodía                 genera, aristogénica, etc.            
            2: difónica                     organum, bourdon                     pitagórica
            3: contrapuntística         polifonía                                    justa
            4: funcional                 homofonía                                temperamentos
            5: tímbrica                 holofonía (?)                                microtonalidad extendida,
                                                                                                 grados de disonancia
            
Barlow habla acerca de un plano consistente en un eje tonalidad-atonalidad y otro eje consonancia-disonancia y se refiere al hecho de que la implicación armónica de un intervalo es diferente a sus implicaciones de aspereza, ya que la escucha de aspereza implica escucha en la dimensión de alto y bajo, tal como en la percepción de fonemas, movimiento y color. En contraste, la escucha armónica implica estabilidad-tensión con respecto a un sistema de relaciones tal y como ocurre en la escucha interválica. Aún así, los intervalos producidos por el análisis de las curvas de disonancia tienen un alto nivel de armonicidad, un acuerdo entre los dos ejes de nuestra escucha de alturas que puede ser pensazdo como ocurriendo en la región abierta de este plano que envuelve al eje de consonancia-disonancia. Una "zona no discernible" donde las cosas pueden ser tanto ásperas como suaves pero a la vez no son ni tonales ni atonales.

Curvas de disonancia:

Las curvas de disonancia están hechas midiendo la aspereza entre dos sonidos al trasponer uno de ellos. Los parciales del sonido de referencia y del transpuesto son pesados unos contra otros de acuerdo a la curva de aspereza de Plomp y Levelt (es decir, de acuerdo al comportamiento de la aspereza según la banda crítica). Esto da como resultado una estimación de la aspereza en función de los intervalos de transposición. Esta investigación se ha limitado en su mayor parte a explorar el análisis de un sonido consigo mismo debido a que hay una gama de posibilidades muy amplias contenidas en esta configuración además de que para dos sonidos distintos, las preguntas composicionales que se plantean divergen del enfoque presente de relacionar timbre, textura y armonía.

f = Array.fill(20, {|i| (i+1) * 49});     // arreglo de frecuencias, 20 parciales armónicos de 49Hz
a = {1}!20; // todos los parciales con la misma amplitud
a = Array.fill(20, {|i| (i + 1).reciprocal}); // arreglo de amplitudes 1/n
a = Array.fill(20, {|i| (i.squared + 1).reciprocal}); // arreglo 1/(n**2)

Debido a las limitaciones de resolución del análisis de Fourier y de la disonancia, el ruido blanco da como resultado una variedad de escalas con características aleatorias:
f = Array.rand(10, 49, 1200).sort; // frecuencias aleatorias: ruido?
a = {rrand(0.1, 1)}!20; // todo aleatorio

// evaluar arreglos f y a (frecuencia, amplitud) arriba y calcular y tocar sus curvas de disonancia:
d = Dissonance.make( f, a, 0.24, 6.01 ); // sobre un intervalo de 0.99 a 3.01 octavas
d.plot;
d.play;
d.correctScale;

Ocurre que cuando se estudian estas asperezas propias de un sonido, estas disonancias intrínsecas, los puntos en donde las curvas alcanzan sus mínimos locales caen muy cerca de intervalos cuya representación racional es de interés armónico. Es por eso que la implementación en la computadora de las curvas da como resultado un conjunto de alturas microtonales para cada pedazo de sonido que se analiza. Estos conjuntos de notas pueden ser tratados tímbricamente para formar acordes congruentes con características tímbricas de la fuente. También se les puede dar un tratamiento armónico, de ahí el interés en producir transiciones entre los modos de escucha tímbricos y armónicos. Para lograr esto, la noción de textura (al nivel de las "notas") nos permite implementar herramientas que ayuden a alcanzar este tipo de transiciones a través de la puesta en movimiento (horizontal y vertical) de las notas. Investigaciones acerca de la percepción de textura en música, basadas en modelos de Gestalt, han dado como resultado tipologías útiles para la generación algorítmica de patrones. La parte  que es de interés para la generación de estas transiciones es la que corresponde al movimiento 'diagonal', resultado de una combinación de configuraciones tanto verticales como horizontales. La fusión y fisión de las notas marcaría las fronteras en estas transiciones, formando un eje divisiorio entre la escucha tímbrica y la armónica.

Hay una relación interesante en cuanto a las escalas producidas cuando los espectros de las fuentes son armónicos. Estas escalas corresponden a afinaciones justas extendidas. Sethares [4] ha dicho que la música occidental usa afinaciones que guardan una estrecha relación con los timbres de sus instrumentos musicales, en particular con la voz y los aerófonos. También que las afinaciones del gamelán están relacionadas con los timbres de sus gongs. Yo creo que está afirmación es demasiado amplia, pero que de hecho la conexión juega un rol y sobre todo que puede ser útil composicionalmente.

Usos composicionales:

Como un compositor asistido por computadora, hay una vasta gama de materiales musicales  derivados de las curvas de disonancia. Algunos acercamientos hasta la fecha son:

            * Componer con un rango amplio de afinaciones relacionadas con timbres
                        - uso de intervalos cuyos límites de números primos son mayores a 5
                          con ayuda de una gramática 'tímbrica'
                        - extensión del solfeo de objetos sonoros con armonía
                        
            * Síntesis de acordes, timbres y texturas
                        - corales de disonancia
                        - armonía granular
                        - harmonie concrète

            * Análisis-síntesis en tiempo real
                        - fantasmas (espectros), criticismo, comentario

Ejemplos:

    Dissophonos:
    this.executeFile("/docs/supercolaider/Dissonance\ Curves/presentation/diss-phonos.rtf");

    (
    q= ();
    q.move = Buffer.read(s,"/docs/supercolaider/Dissonance\ Curves/experimentos/gottamove\[0\].wav");
    q.cpe = Buffer.read(s,"/docs/supercolaider/Dissonance\ Curves/presentation/snds/cpe_bach.aif");
    q.duchamp1 = Buffer.read(s, "/Users/jslach/SuperCollider3/build/recordings/SC_duchamp.aiff");
    q.duchamp2 = Buffer.read(s, "/docs/supercolaider/Dissonance\ Curves/experimentos/duchampHarG\[1\].wav");
    q.pauwels = Buffer.read(s, "/docs/supercolaider/Dissonance\ Curves/presentation/snds/pauwels.aif");
    )

    q.duchamp1.play;
    q.cpe.play;
    q.duchamp2.play;
    q.move.play;

    Live-dissonance:
    this.executeFile("/docs/rolax/tomma/live_ifft_recordert\[0\].rtf");

    q.pauwels.play;

    Piezas:
                - rolita pa modelo
                - 'strings'
                - boceto marimba
                        
Conclusiones:

“El timbre puede ser considerado como un caso especial de armonía, que a su vez es un caso especial de ritmo. La textura puede ser considerada como una expansión del timbre y conversamente, el timbre puede ser visto como un caso limítrofe de textura, con un área gris entre los dos.
Hay también estados limítrofes entre textura e intervalos y entre textura y ritmo. Cambios rápidos o pequeños en la altura o duración junto a constreñimientos psicoacústicos previenen la clara identificación de alturas, intervalos o ritmos. Las situaciones en las cuales los intervalos se transforman en textura son intencionales en muchas culturas no occidentales así como en la música contemporánea." Ver Cohen y Dubnov (1997) [5].


Bibliografía:

[3]    Barlow, C. (1980). Bus Journey to Parametron. Cologne: Feedback Papers 21-23. Köln: Feedback Studio Verlag.
        Barlow, C. (1987). Two Essays on Theory. Computer Music Journal 11, 44-60.
        Benson, D. (1995-2007). Music: A Mathematical Offering. Capítulo 4.
            Obtenible en: http://www.maths.abdn.ac.uk/~bensondj/html/maths-music.html
[5]    Cohen, D. y Dubnov, S. (1997). Gestalt Phenomena in Musical Texture. En Leman, M. (Ed.),  Music, Gestalt, and
            Computing (386-403). Berlin–Heidelberg: Springer.
        Helmholtz, H.L.F. (1877). On the Sensations of Tone as a Psychological basis for the Theory of Music. New York: Dover.
        Plomp R. y Levelt, W. (1965). Tonal Consonance and Critical Bandwidth. Journal of the Acoustical Society
            of America #38, 548-568.
        Porres, A.T y Manzolli, J. (2003). Um Modelo Psicoacústico de Rugosidade. PDF obtenida de los autores. (En portugués).
        Schaeffer, P. (1988 [1966]). Tratado de los objetos musicales. (traducción del Traite des Objets Musicaux (version abrigeé)
        por Araceli Cabezón de Diego). Alianza: Madrid
[4]    Sethares, W. (1997). Tuning, Timbre, Spectrum, Scale. Berlin: Springer.
        Tenney, J. (1984). John Cage and the Theory of Harmony. Soundings 23. Soundings press.
[2]    Tenney, J. (1988). A History of 'Consonance and Dissonance'. New York: Excelsior Music Publishing.
[1]    Vassilakis, P.N. (2001) Perceptual and Physical Properties of Amplitude Fluctuation and their Musical Significance.  
            Tésis de doctorado. UCLA. Obtenible en: http://www.acousticslab.org/papers/diss.htm
            
(cc 2007-2008) Juan Sebastián Lach Lach.  http://homepage.mac.com/jslach/

 

Puedes bajar la conferencia desde este link

DisonanciaJSLach.RTF

 
Puedes bajar el archivo dissonance.zip donde se encuentran las "Classes" y los archivos de "Help" necesarios para correr los códigos de SuperCollider de Juan Sebastian. Al desomprimir el archivo deberás guardarlo en

 
 /Users/tait_mx/Library/Application Support/SuperCollider/Extensions

 
o siguiendo el path que te indique el Collider al declarar la línea de código siguiente:


Platform.userExtensionDir